Il y a une explication actualisée sur la manière de le résoudre sur les forums Steam . Si, pour une raison quelconque, il devient inaccessible, voyez mon explication ci-dessous sur la façon de le réparer.
Ça ne marche toujours pas ? Voici comment le réparer. La plupart des crédits vont à un type surnommé Darkje - merci Darkje ! J'ai préparé un seul zip pour accélérer le processus.
Méthode courte
- Téléchargez le zip suivant : maxpaynesoundfix.zip .
- Extrayez-le dans le dossier d'installation de Max Payne (avec Steam, ce doit être le dossier suivant
<base Steam folder>\steamapps\common\max payne ).
- Double-cliquez sur le
MaxBatch.bat et attendez qu'il soit terminé. Certains avertissements peuvent apparaître - ignorez-les.
- Jouez le jeu !
Si vous ne pouvez pas télécharger le zip pour une raison quelconque, vous pouvez utiliser la méthode longue.
Méthode longue
Étape 1 : obtenir SoX
Vous avez besoin d'une distribution de SoX Un utilitaire qui permet de convertir des fichiers sonores d'un format à un autre. Voici un lien direct vers la page de téléchargement - téléchargez simplement le fichier se terminant par win32.zip . Pour référence future, la version qui a fonctionné pour moi était la 14.3.1.
Extrayez le zip téléchargé quelque part, puis copiez les fichiers suivants dans le dossier Max Payne (comme indiqué ci-dessus dans la méthode courte) :
sox.exe
libgomp-1.dll
pthreadgc2.dll
Étape 2 : obtenir RASMaker
RASMaker est un outil 3D-Realms utilisé pour extraire le .ras qui contiennent toutes les ressources du jeu, y compris les sons. Vous pouvez le télécharger en tant que partie du paquet " MAX-FX Tools ", qui J'ai pu trouver sur le site levels4you . Malheureusement, le site exige une inscription pour télécharger des fichiers. De plus, vous devez installer l'application téléchargée.
Une fois que vous l'avez installé, copiez les deux fichiers suivants depuis le dossier <fx-tools installation directory>\RasMaker\ dans le dossier Max Payne :
RASMaker.exe
rl.dll
Après avoir copié ces fichiers, vous pouvez supprimer l'application FX Tools installée.
Étape 3 : créer le fichier batch
Le texte suivant est le code d'un fichier batch Windows. Il a été écrit par Darkje et édité par moi (mon édition est mineure, cependant, elle était juste nécessaire pour mettre à jour la version originale de Darkje pour fonctionner avec la version actuelle de SoX).
Pour créer le fichier, créez d'abord un nouveau fichier texte vierge, puis copiez-y le texte suivant, et enfin renommez-le en MaxBatch.bat et le mettre dans le dossier d'installation de Max Payne.
@echo off
cls
rem --- v0.2 28-Aug-07 ---
echo *** MaxPayne vista sound conversion script by Darkje ***
echo.
echo Welcome!
echo.
rem --- directory setup ---
rem --- default . requires all files in the game dir ---
rem --- specify paths if you like to use the files from an other dir. ---
set rasdir=.
set gamedir=.
set soxdir=.
rem --- restore if backup data deteced ---
if exist "%gamedir%\moved" goto rasrestore
rem --- check paths ---
if not exist "%rasdir%\rasmaker.exe" goto noras
if not exist "%rasdir%\rl.dll" goto norl
if not exist "%gamedir%" goto nogame
if not exist "%soxdir%\sox.exe" nosox
rem --- show paths found ---
echo RASmaker is found in: %rasdir%
echo Game dir is found at: %gamedir%
echo Sox is found in: %soxdir%
rem --- check if the ras files are there ---
if not exist "%gamedir%\x_data.ras" goto rasmis
if not exist "%gamedir%\x_level1.ras" goto rasmis
if not exist "%gamedir%\x_level2.ras" goto rasmis
if not exist "%gamedir%\x_level3.ras" goto rasmis
if not exist "%gamedir%\x_music.ras" goto rasmis
echo Required ras files found!
echo.
rem --- unpack ---
echo Unpacking...
echo.
for %%i in (*.ras) do "%rasdir%\rasmaker.exe" -x "%gamedir%\%%i" "%gamedir%"
echo.
rem --- convert by calling sox batchfile in a loop ---
echo converting wave files ...
for /r .\data %%i in (*.wav ) do call :convert "%%i"
echo.
rem --- create moved dir, and move ras files there ---
echo Moving ras files ...
if not exist "%gamedir%\moved" mkdir "%gamedir%\Moved"
copy "%gamedir%\*ras" "%gamedir%\moved"
echo.
echo Cleaning up ...
echo.
del "%gamedir%\*.ras"
rem --- all ok ---
echo All done, Game unpacked, Sounds converted.
echo Run Maxbatch again to restore.
echo Thanks for using MaxBatch.
goto end
rem --- subroutines ---
rem --- convert with sox ---
:convert
%soxdir%\sox -q %1 -u -b 8 "%~d1%~p1outfile.wav"
del %1
ren "%~d1%~p1outfile.wav" %~nx1
goto :EOF
rem --- goto's ---
rem --- restore game ---
:rasrestore
if not exist "%gamedir%\moved\x_data.ras" goto rasmisb
if not exist "%gamedir%\moved\x_level1.ras" goto rasmisb
if not exist "%gamedir%\moved\x_level2.ras" goto rasmisb
if not exist "%gamedir%\moved\x_level3.ras" goto rasmisb
if not exist "%gamedir%\moved\x_music.ras" goto rasmisb
echo Backup files exist, restore original condition?
echo The ras files will be moved back to the 'Max Payne' dir,
echo extracted and modified data will be deleted,
echo restoring the game to its original condition.
echo.
echo To cancel press Ctrl+C followed by Y[enter] to quit now!
pause
echo.
echo Moving ras files back...
copy "%gamedir%\moved\*.ras" "%gamedir%"
echo.
echo Cleaning up ...
rmdir /s /q "%gamedir%\moved"
rmdir /s /q "%gamedir%\data"
echo.
echo All done, Game restored. Thanks for using MaxBatch.
goto end
rem --- ras file(s) missing ---
:rasmis
echo Error: A ras file was not found, aborting!
goto end
:rasmisb
echo Error: A backup file was not found, cannot restore, aborting!
goto end
rem --- no sox ---
:nosox
echo Error: Sox.exe not found!
echo place it in your max payne game directory and retry.
goto end
rem --- no rasmaker ---
:noras
echo Error: Rasmaker not found!
echo place it in your max payne game directory and retry.
goto end
rem --- no rl.dll ---
:norl
echo Error: rl.dll not found!
echo place it in your max payne game directory and retry.
goto end
rem --- no game ---
:nogame
echo Error: The path you specified as game directory does not exist!
goto end
rem --- end progam ---
:end
rem --- clean up vars ---
set rasdir=
set gamedir=
set rasdir=
rem --- wait for key and exit ---
echo.
pause
Étape 4 : exécuter le fichier batch et lancer le jeu
A présent, votre dossier Max Payne devrait contenir 6 nouveaux fichiers - 3 de SoX, 2 de RASMaker, et le fichier MaxBatch.bat fichier. Il s'agit des mêmes fichiers que ceux que vous auriez obtenus à partir du zip non téléchargeable - il suffit donc de passer à l'étape 3 de la méthode courte.
Notes
- L'exécution du fichier batch peut prendre quelques minutes, soyez patient.
- Si quelque chose s'est mal passé, vous pouvez simplement exécuter la commande
MaxBatch.bat de nouveau - cela restaurera les fichiers dans leur forme originale.
- Cela va probablement no ne fonctionne pas avec un jeu moddé :(
- Pendant l'exécution du lot, SoX a signalé un grand nombre d'avertissements de "dither" pour moi, dans le format :
sox WARN dither: dither clipped <num> samples; decrease volume? . Cela n'a pas semblé causer de problème, cependant.
